
    Changelog

v0.10.1 (2026-09-29)
Bug fixes
	Fix planned from transitions using a source trait that an earlier command
had already removed.
	Fix transitions incorrectly rejected when their source trait was added by
a later invocation of the same command.

v0.10.0 (2026-09-27)
Features
	Add parameterized traits: declare args_pattern: %{age: _} and pass a value
with produce(ctx, user: [:active, age: 18]). Parameterized traits also work
in with_traits, and their values are tracked after both produce and exec.

Changes
	Validate with_traits references at schema compilation, reporting invalid
references with Spark.Error.DslError instead of failing during planning.
	Reject conflicting :as bindings and malformed trait entries in produce
and pre_produce with ArgumentError instead of silently ignoring them.
Unknown traits raise SeedFactory.UnknownTraitError.
	Report conflicting traits across repeated entity entries with
SeedFactory.TraitRestrictionConflictError, consistently with a single entry,
instead of SeedFactory.TraitResolutionError.

Bug fixes
	Apply traits listed after :as in produce and pre_produce requests.
	Fix args_pattern matching against structs and nested patterns against
scalar arguments, which previously raised exceptions.
	Remove all occurrences of a trait during a from transition, including
traits applied by multiple commands.

Requirements
	Raise the minimum Spark version to 2.7.3 (~> 2.7 and >= 2.7.3).

v0.9.0 (2026-09-11)
The planning behind produce, pre_produce, exec and pre_exec was rebuilt.
What you can rely on
	After produce, every requested entity is in the context, with every requested trait. A request that cannot be honoured fails before anything runs. Previously such a request could return a context silently missing the entity or the trait, or crash halfway through the execution.
	Plans that need an alternative are found: another command producing the entity, another route to a trait, a command re-producing an entity after a deleting command consumed it. Previously these requests failed with a false circular-dependency or trait error.
	Entities already in the context are respected: a command re-producing one needs a deleting command in between, and the commands consuming, deleting and re-producing it run in a valid order. Previously that order could depend on command names and crash or hand a command an entity in the wrong state.
	A command runs only once the entities its params name exist and carry the traits their with_traits ask for at that moment. Previously a planned command could receive an entity a later-planned command had already stripped of the trait, or one it had deleted.
	A request is a set: the plan does not depend on the order of its entries or of the traits within an entry. Previously the entity named first could pick a producer the others then had to live with, and the same request written in another order produced different side entities and traits.
	pre_produce prepares the dependencies of the requested entities even when producing everything in one produce call would be impossible, and never consumes an entity the request names.

What changed for schemas
	The generate functions of params and the generate_args functions of trait declarations run once, while the plan is built and before any command executes; the execution reuses the values. Keep them to producing values (random data, counters), without writes to a database or a file.
	A trait declared with from replaces the named trait, and a command that later asks for the replaced trait through with_traits is refused, where it used to run. A trait that adds a property without leaving the previous state is declared without from.

Requirements
	Elixir 1.19 or later. The previous minimum was 1.15.

Errors
A refused request explains every candidate it rejected:
cannot produce entity :contract: no candidate command fits the plan
- :sign_contract would duplicate existing :contract_copy (rebind or delete it first)
- :import_contract would duplicate existing :approval (rebind or delete it first)
A plan that would end without a requested trait raises SeedFactory.MissingRequestedTraitError, naming the command whose transition removes the trait.
SeedFactory.ConflictingTraitsError is gone. Two requested traits whose commands would both produce the same entity are refused with the reason also produces :x, already produced by :y in this plan. A request one command can serve on its own now succeeds, where the removed check refused it.
A request asking for a trait together with one that replaces it is refused naming the request. The message used to name a nil command.
Bug fixes
	A requested trait consumed by a transition declared with a from list was silently skipped. It now raises, like a transition declared with a single from.
	with_traits on an entity param accepted an entity that had gone through the required trait and lost it. It now raises, or uses another candidate when one exists.
	Trait resolution gave up when the first option of a from list could not be satisfied. The options are now tried in the declared order.
	A trait declared on several commands was reported as a mismatch when one executed command did not add it while another did. Every executed declaration is now reported.
	Input for a param nested in a param ... do ... end container did not cover the dependency: the command producing it still ran.
	The compile-time trait cycle check missed a cycle through a from edge of a shadowed declaration. Such a schema compiled and could hang produce.

v0.8.2 (2026-08-18)
Bug Fixes
	Fix trait resolution depending on the order of traits in a produce request. A trait declared on a single command now wins conflict resolution regardless of its position in the list, and conflicting trait requests raise SeedFactory.TraitResolutionError instead of silently producing the entity through another command.
	Fix missing execution-order edges after conflict resolution removes a producer another node depended on. Could surface as KeyError depending on the topological sort tie-break.
	Fix produce silently returning an incomplete context when the selected commands form a circular dependency. Now raises SeedFactory.CircularDependencyError naming the commands.
	Fix with_traits on an entity param being ignored when selecting the producer of an absent dependency while the demanding command was still in unresolved conflict groups. Such a demand now wins conflict resolution once the demanding command settles in the plan, and expires when that command leaves it.

v0.8.1 (2026-08-17)
Bug Fixes
	Fix FunctionClauseError when producing a second instance of an entity via rebinding and every producing command would duplicate an existing entity. Now raises SeedFactory.EntityAlreadyExistsError naming the entity that must be rebound.
	Fix missing execution-order edges for commands that are re-executed under rebinding. Could surface as KeyError depending on topological sort tie-break.
	Fix args of a trait declared on several commands leaking into the command that did not declare them. produce then failed with "Input doesn't match defined params".

v0.8.0 (2026-03-29)
Features
	Add SeedFactory.ExecError — structured exception for resolver failures with execution plan, trails, and current traits
	Add execution history to meta (execution_history) that records all produce/exec calls with caller, rebinding, and executed commands
	Add Context.track_execution/3 for automatic execution tracking
	Add custom Inspect for SeedFactory.Execution with compact #execution[...] format

Breaking Changes
	Resolver {:error, error} now raises SeedFactory.ExecError instead of RuntimeError

Performance
	Replace libgraph dependency with inline topological sort
	Optimize compile-time trait indexing
	Fix quadratic list accumulation in scan_subsequent_traits

Improvements
	Improved documentation for core functions, SeedFactory.Schema, and SeedFactory.Test modules

v0.7.1 (2026-03-26)
Bug Fixes
	Fix trait-resolved node being overwritten by later conflict resolution
	Fix warning from ex_docs
	Fix flaky test

Improvements
	Skip coverage for test/support files
	Update dependencies

v0.7.0 (2026-01-31)
Features
	Same trait can be set by multiple commands
	"Did you mean?" suggestions in compile-time errors for typos

Compile-time Validations
	Validate referenced entities in params
	Validate circular trait dependencies
	Validate trait references in :from option (non-existent trait, wrong entity)

Bug Fixes
	Fix trait transition execution order
	Fix trait resolution for commands in conflict groups
	Fix :is_subset conflict resolution removing commands in multiple groups
	Fix trait resolution when command produces multiple entities

Improvements
	Major internal refactoring - extracted modules: Context, Requirements, CommandGraph, Exceptions
	Improved exception messages with better context
	Improved error reporting
	Better error message when produced entity was already produced by another command
	Hide __spark_metadata__ from inspect output
	Compile test support files

Dependencies
	Updated Spark and other dependencies

v0.6.0 (2024-05-17)
Features
	:from option now accepts list of traits - a trait can replace multiple parent traits:trait :suspended, :user do
  from [:pending, :active]  # Can transition from either state
  exec :suspend_user
end


Bug Fixes
	Match generated args by args_match function when there's a conflict - fixes cases when generate_args has randomness
	Don't treat structs as maps in deep comparison/merging

Improvements
	Better error message when entity was put manually into context without using SeedFactory

Breaking Changes
	Requires Elixir ~> 1.15 (due to Spark ~> 2.1 dependency)

v0.5.0 (2024-03-12)
Features
	Multiple commands can produce the same entity - the first defined command becomes the default
	Automatic command selection based on trait restrictions - when traits require a specific command that produces the entity, SeedFactory automatically switches to that command

Improvements
	Better conflict resolution when merging trait arguments
	Validate entity existence in rebind/3 - raises ArgumentError for unknown entities
	Custom Inspect implementation for SeedFactory.Command for cleaner output

Bug Fixes
	Fix producing entity with traits when it already exists without traits

Error Messages
	Show command name when merging of args fails
	Show command name in errors when entity doesn't exist
	Helpful message when produce is called with 1 argument incorrectly
	Disallow nil command names

Validations
	:with_traits option must be used only for parameters with type :entity

v0.4.0 (2023-08-16)
Features
	Schema composition - include other schemas using include_schema MyApp.OtherSchema to reuse commands and traits
	generate_args and args_match options for traits - more flexible alternative to args_pattern for dynamic trait matching:trait :expired, :project do
  exec :publish_project do
    args_match(fn args -> Date.compare(Date.utc_today(), args.expiry_date) == :gt end)
    generate_args(fn -> %{start_date: Date.add(today, -22), expiry_date: Date.add(today, -1)} end)
  end
end


Improvements
	:from option is now optional for produce and update instructions - defaults to entity name
	Allow param/1 macro without parentheses in formatter

v0.3.0 (2023-07-23)
Features
	Traits support - labels assigned to entities when specific commands are executed. Allows requesting entities with specific traits via produce(context, user: [:admin, :active])
	pre_exec/3 - creates dependencies needed to execute a command, useful when executing the same command multiple times
	pre_produce/2 - produces dependencies needed for specified entities

Breaking Changes
	DSL syntax for parameters changed:# Before (v0.2.0)
param :name, &Faker.Person.name/0
param :role, fn -> :normal end
param :company, :company

# After (v0.3.0)
param :name, generate: &Faker.Person.name/0
param :role, value: :normal
param :company, entity: :company

	Renamed internal :commands DSL section to :root

Improvements
	Friendly error when unknown command is passed to exec
	Raise error if unknown entity is passed to produce
	Allow rebinding to the same value (no longer raises)
	Compile-time validations for traits
	Exported formatter settings for exec/1-2 and from/1

v0.2.0 (2023-06-07)
Features
	Support nested rebinding - rebind/3 can now be nested, merging rebindings at each level and properly restoring previous state after callback completion. Raises on rebinding conflicts.

Improvements
	Raise an error when redundant keys are passed to a command (keys not defined in params)

v0.1.0 (2023-05-06)
Initial release.
Features
	Schema DSL for defining entities and commands
	Command system with:	produce - for creating entities
	update - for modifying entities
	delete - for removing entities


	Parameter handling with support for generating values and dependencies on other entities
	Test utilities (SeedFactory.Test) for using in ExUnit tests
	Compile-time verification of dependencies between commands and entities

A toolkit for test data generation.
The main idea of SeedFactory is to generate data in tests according to your application business logic (read as
context functions if you use Phoenix Contexts) whenever possible
and avoid direct inserts to the database (as opposed to ex_machina).
This approach allows you to minimize testing of invalid states as you're not forced to keep complex database structure in your head in order to prepare test data.
The library is completely agnostic to the database toolkit.
Core concepts
Context is a map/0 which can be populated with entities using commands.
The schema with instructions on how commands modify context is described using DSL with the help of SeedFactory.Schema module.
Commands can be used to:
	produce entity (put new data in the context)
	update entity (replace the existing entity in the context)
	delete entity (remove the entity from the context)

A command has params with instructions on how to generate arguments for a resolver if they are not passed explicitly with exec/3 function.
The instruction can be specified using one of these options:
	:value - any term. This option is used by default with the value of nil.
	:generate - a zero-arity function for generating data.
	:entity - an atom which points to an entity which should be taken from the context. If a required entity cannot
be found in a context, then SeedFactory automatically executes a corresponding command which produces the entity.
The :entity option also supports :with_traits to require that the entity has specific traits before it can be used as a dependency.

Traits are labels assigned to entities when specific commands with specific arguments are executed.
They describe how an entity was created or what state it is in. Use from for state transitions:
an :active trait declared with from :pending replaces :pending. Omit from to add a trait without
replacing another. Traits can also be tied to specific argument values using args_pattern.
Schema example
defmodule MyApp.SeedFactorySchema do
  use SeedFactory.Schema

  command :create_company do
    param :name, generate: &Faker.Company.name/0

    resolve(fn args ->
      with {:ok, company} <- MyApp.Companies.create_company(args) do
        {:ok, %{company: company}}
      end
    end)

    produce :company
  end

  command :create_user do
    param :name, generate: &Faker.Person.name/0
    param :role, value: :normal
    param :company, entity: :company

    resolve(fn args -> MyApp.Users.create_user(args.company, args.name, args.role) end)

    produce :user
    produce :profile
  end

  command :activate_user do
    # with_traits ensures the user has the :pending trait before activation
    param :user, entity: :user, with_traits: [:pending]

    resolve(fn args ->
      user = MyApp.Users.activate_user!(args.user)

      {:ok, %{user: user}}
    end)

    update :user
  end

  # :pending is assigned when :create_user is executed
  trait :pending, :user do
    exec :create_user
  end

  # :activate_user replaces :pending with :active
  trait :active, :user do
    from :pending
    exec :activate_user
  end

  # :admin and :normal are determined by the :role argument
  trait :admin, :user do
    exec :create_user, args_pattern: %{role: :admin}
  end

  trait :normal, :user do
    exec :create_user, args_pattern: %{role: :normal}
  end
end
Getting started
To start using the schema, put metadata about it to the context using init/2 function:
context = %{}
context = init(context, MyApp.SeedFactorySchema)
If you use SeedFactory in tests with ExUnit, check out SeedFactory.Test. This module adds initialization using ExUnit.Callbacks.setup_all/2 callback
and imports functions.
exec
exec/2 function can be used to execute a command:
context = exec(context, :create_company)
The code above will generate arguments for :create_company command, execute a resolver with generated arguments and put company to context using :company key.
exec/3 can be used if you want to specify parameters explicitly:
context = exec(context, :create_company, name: "GitHub")
Because exec function returns context/0, it is convenient to chain exec calls with the pipe operator:
context =
  context
  |> exec(:create_company)
  |> exec(:create_user, name: "John Doe")
In order to get a value for the :company parameter of the :create_user command, the corresponding entity was taken from the context.
However, it is not necessary to do so, as SeedFactory can automatically execute commands which produce dependent entities.
The code above has the same effect as a single call to :create_user command:
context = exec(context, :create_user, name: "John Doe")
produce
If you're not interested in explicitly providing parameters to commands, you can use produce/2 to produce
requested entities with automatic execution of all dependent commands:
context = produce(context, :user)
Even though :user is the only entity specified explicitly, context will have 3 new keys: :company, :user and :profile.
Traits can be specified to control how entities are created. SeedFactory figures out
the command chain from the trait definitions:
# these two are equivalent
context = produce(context, user: [:admin, :active])

context =
  context
  |> exec(:create_user, role: :admin)
  |> exec(:activate_user)
Use the :as option to combine traits with rebinding:
%{active_admin: active_admin} = produce(context, user: [:admin, :active, as: :active_admin])
Tip
Pattern match on what you pass to produce/2. This makes the test self-documenting
and avoids relying on implicitly created entities:
# good — matches what was requested
%{user: user} = produce(context, :user)

# good — multiple entities requested and matched
%{user: user, profile: profile} = produce(context, [:user, :profile])

# bad — matching entities that were not explicitly requested
%{user: user, profile: profile, company: company} = produce(context, :user)
Rebinding
exec/3 fails if produced entities are already present in the context.
It is possible to rebind entities in order to assign them to the context with different names:
context =
  context
  |> rebind([user: :user1, profile: :profile1], &exec(&1, :create_user))
  |> rebind([user: :user2, profile: :profile2], &exec(&1, :create_user))
The snippet above puts the following keys to the context: :company, :user1, :profile1, :user2 and :profile2.
The :company is shared in this case, so two users have different profiles and belong to the same company.
A shorter counterpart using produce/2 is the following:
context =
  context
  |> produce(user: :user1, profile: :profile1)
  |> produce(user: :user2, profile: :profile2)
Debugging
SeedFactory tracks how each entity was created and modified.
You can inspect __seed_factory_meta__ key in the context to review currently assigned traits and execution history:
context |> produce(user: [:admin, :active]) |> IO.inspect()
# %{
#   __seed_factory_meta__: #SeedFactory.Meta<
#     current_traits: %{company: [], profile: [], user: [:admin, :active]},
#     trails: %{
#       company: #trail[:create_company],
#       profile: #trail[:create_user],
#       user: #trail[create_user: +[:admin, :pending] -> activate_user: +[:active] -[:pending]]
#     },
#     execution_history: [
#       #execution[produce(user: [:admin, :active]): create_company → create_user → activate_user]
#     ],
#     ...
#   >,
#   company: %Company{...},
#   profile: %Profile{...},
#   user: %User{...}
# }
If an exception or error occurs during command execution, SeedFactory raises SeedFactory.ExecError
with structured metadata including the execution plan, trails, and current traits at the time of failure:
** (SeedFactory.ExecError) unable to execute :create_user command: :email_already_taken

Execution plan:
  ✔ :create_company
  ✖ :create_user

Current traits:
  %{company: []}

          @type entity_name() :: atom()


      



  



  
    
      
    
    
      rebinding_rule()



        
          
        

    

  


  

      

          @type rebinding_rule() :: {entity_name(), rebind_as :: atom()}

          @type trait_name() :: atom()

          @type trait_request() ::
  trait_name() | {trait_name(), value :: term()} | {:as, rebind_as :: atom()}

          @spec exec(context(), command_name :: atom(), initial_input :: map() | keyword()) ::
  context()


      


Executes a command and updates the context according to the schema.
Example
iex> context = %{}
...> context = init(context, MySeedFactorySchema)
...> context = exec(context, :create_user, first_name: "John", last_name: "Doe")
...> Map.take(context.user, [:first_name, :last_name])
%{first_name: "John", last_name: "Doe"}

          @spec init(context(), schema :: module()) :: context()


      


Puts metadata about schema to context, so context becomes usable by other functions from this module.
Example
iex> context = %{}
...> init(context, MySeedFactorySchema)
%{__seed_factory_meta__: #SeedFactory.Meta<...>}

          @spec pre_exec(context(), command_name :: atom(), initial_input :: map() | keyword()) ::
  context()


      


Creates all dependent entities needed for a command, without executing the command itself.
This is useful when you want to execute the same command multiple times with shared dependencies.
It is especially handy when a command has many dependencies — pre_exec resolves all of them
automatically, so you don't have to enumerate them yourself.
Example
Consider a schema where :publish_article depends on :blog, :category,
and :author (with trait :active):
command :publish_article do
  param :blog, entity: :blog
  param :category, entity: :category
  param :author, entity: :author, with_traits: [:active]
  param :title, generate: &Faker.Lorem.sentence/0
  # ...
  produce :article
end
Without pre_exec, you would have to manually set up all the dependencies:
context = produce(context, [:blog, :category, author: [:active]])

%{article: article1} = exec(context, :publish_article, title: "First")
%{article: article2} = exec(context, :publish_article, title: "Second")
With pre_exec, the same is achieved without knowing the dependency tree:
context = pre_exec(context, :publish_article)

%{article: article1} = exec(context, :publish_article, title: "First")
%{article: article2} = exec(context, :publish_article, title: "Second")

          @spec pre_produce(
  context(),
  entity_name()
  | [entity_name() | rebinding_rule() | {entity_name(), [trait_request()]}]
) :: context()


      


Produces all dependencies needed for specified entities, without producing the entities themselves.
Works like pre_exec/3, but operates on entities instead of commands. The dependency tree
is derived from the commands that would produce the requested entities.
When traits are specified, the full command chain is analyzed — including update commands.
All their dependencies are created, but the requested entity itself is not.
For example, if :activate_user updates :user and depends on :team,
then pre_produce(context, user: [:active]) will create :team (and all other
dependencies in the chain) without creating the :user.
Examples
# Create all dependencies for :article (e.g. :blog, :category, :author)
# without creating the article itself
context = pre_produce(context, :article)

%{article: article1} = produce(context, :article)
%{article: article2} = produce(context, :article)
Accepts a list with traits, same as produce/2:
context = pre_produce(context, [:article, user: [:active, :admin]])

          @spec produce(
  context(),
  entity_name()
  | [entity_name() | rebinding_rule() | {entity_name(), [trait_request()]}]
) :: context()


      


Produces entities with their dependencies resolved automatically.
Analyzes the schema to determine which commands need to be executed and in what order.
Entities that already exist in the context are reused. The order of specified entities
doesn't matter.
Examples
# produce a single entity (dependencies like :company are created automatically)
%{user: _} = produce(context, :user)

# produce multiple entities
%{user: _, company: _} = produce(context, [:user, :company])

# rebind entity to a different name
%{user1: _} = produce(context, user: :user1)

# specify traits
%{user: _} = produce(context, user: [:active, :admin])

# pass a value to a trait declared with args_pattern: %{age: _}
%{user: _} = produce(context, user: [:active, age: 18])

# apply traits incrementally — first create a pending admin, then activate
%{user: _} = context |> produce(user: [:pending, :admin]) |> produce(user: [:active])

# combine traits with rebinding using :as option
%{user1: _} = produce(context, user: [:active, :admin, as: :user1])
Multiple commands producing the same entity
If the same entity can be produced by multiple commands, the first declared command
is used by default. Traits allow you to pick a specific command. For example, given:
command :create_draft_project do
  # ...
  produce :draft_project
end

command :import_draft_project do
  # ...
  produce :draft_project
end

trait :created, :draft_project do
  exec :create_draft_project
end

trait :imported, :draft_project do
  exec :import_draft_project
end
Then:
# uses :create_draft_project (first declared) and assigns the :created trait
produce(context, :draft_project)

# equivalent to the above, but explicit
produce(context, draft_project: [:created])

# uses :import_draft_project
produce(context, draft_project: [:imported])
Requested traits also influence how other entities in the plan are produced.
A command that satisfies a requested trait is preferred for every entity it
produces, so related entities come from the same command whenever possible.
The declaration order decides among equally preferred commands. When the
preferred command cannot be part of the plan, another command that produces
the entity is used.

          @spec rebind(context(), [rebinding_rule()], (context() -> context())) :: context()


      


Creates a scoped context where entities are assigned under different names.
Within the callback, all commands that produce, update, delete, or depend on
the specified entities will use the remapped names. The rebinding is scoped to
the callback — it does not affect the context outside of it.
This is useful when you need to produce the same entity multiple times and
control how they relate to each other. For simpler cases where you don't need
to control relationships, produce/2 with rebinding is enough:
context |> produce(company: :company1) |> produce(company: :company2)
Example
# :product requires :company. Here we create 2 companies and 1 product.
# Inside the first rebind, :company refers to :company1 and :product to :product1,
# so the product is linked to company1.
%{company1: _, company2: _, product1: _} =
  context
  |> rebind([company: :company1, product: :product1], fn context ->
    context
    |> exec(:create_company, name: "GitHub")
    |> produce(:product)
  end)
  |> rebind([company: :company2], fn context ->
    exec(context, :create_company, name: "Microsoft")
  end)

A DSL for defining schemas that describe how commands modify context.
To use the DSL, create a schema module:
defmodule MyApp.SeedFactorySchema do
  use SeedFactory.Schema
end
Commands
Commands are the central building block of a schema — they define how entities
are created, updated, and deleted. Entities and traits don't exist on their own;
they are always a result of executing a command.
Use the command macro to define a command. Inside the command block,
you can define input parameters, a resolution, and produce, update, and delete directives.
command :create_user do
  # Parameters, resolution, produce, update, and delete directives
end
Parameters
Parameters define the inputs for the command's resolver function and how default values should be generated.
Parameters can be defined using the param macro and can have an arbitrary level of nesting.
Options
	:value - a static default value. Applied by default as value: nil.

	:generate - a zero-arity function that generates data. For the commands of a plan it
runs once while the plan is built, before any command executes, and the execution reuses
the value. Keep it to producing a value (random data, a counter): no writes to a database
or a file.

	:entity - refers to an entity within the context. If the entity is not in the context,
SeedFactory will automatically execute a command that produces it.

	:with_traits - a list of trait names or {name, value} pairs for parameterized traits. Requires :entity option.
SeedFactory creates the entity or applies the missing traits before the command runs.
If it cannot satisfy these requirements, the request fails before execution.
Note
:with_traits is only used for automatic dependency resolution. If you explicitly pass
the entity as a parameter via exec/3, the traits are not validated.

	:map - a function that maps the entity to another value. Requires :entity option.


command :create_employee do
  param :address do
    param :city, value: "Lemberg"
    param :street, generate: &random_street/0
  end

  param :paid_by, entity: :user, with_traits: [:active]
  param :office_id, entity: :office, map: & &1.id

  param :github_username
  # the line above is equivalent to
  # param :github_username, value: nil

  # resolve, produce, etc.
end
Resolution
The resolve macro defines the logic executed when the command is invoked.
The resolver is a function that takes args and must return either:
	{:ok, map} — where keys are atoms used by :from option in produce and update directives
	{:error, reason} — aborts execution by raising SeedFactory.ExecError

command :create_user do
  param :name, generate: &Faker.Person.name/0
  param :email, generate: &Faker.Internet.email/0

  resolve(fn args ->
    user = MyApp.insert_user!(args)
    {:ok, %{user: user}}
  end)

  produce :user
end
Producing Entities
The produce directive specifies that the command will put a new entity to the context.
Options
	:from - an atom that specifies the key of the map returned by the resolver. Defaults to the entity name.

command :register_user do
  param :name, generate: &Faker.Person.name/0
  param :company, entity: :company

  resolve(fn args ->
    {user, profile} = MyApp.register_user!(args)
    {:ok, %{user: user, profile: profile}}
  end)

  produce :user
  produce :user_profile, from: :profile
end
Updating Entities
The update directive modifies an existing entity within the context.
Options
	:from - an atom that specifies the key of the map returned by the resolver. Defaults to the entity name.

command :update_user do
  param :user, entity: :user
  param :profile, entity: :user_profile

  resolve(fn args ->
    {user, profile} = MyApp.update_user!(args.user, args.profile)
    {:ok, %{user: user, profile: profile}}
  end)

  update :user
  update :user_profile, from: :profile
end
Deleting Entities
The delete directive removes an entity from the context.
command :delete_user do
  param :user, entity: :user

  resolve(fn args ->
    MyApp.delete_user!(args.user)
    {:ok, %{}}
  end)

  delete :user
end
Traits
The trait directive declares a trait for an entity.
The first argument is the trait name, the second is the entity name.
A trait must contain an exec directive with the name of the command.
Executing that command marks the entity with the trait.
Options
	:from - the trait or list of traits this transition replaces.
To plan a transition, SeedFactory requires at least one source trait to be present when its command runs.
For example, from :pending requires :pending; from [:pending, :active] allows either.
Applying the new trait removes all listed source traits that are present.
Omit from to add a trait without replacing another.

trait :pending, :user do
  exec :create_user
end

trait :active, :user do
  from :pending
  exec :activate_user
end

# :suspended can replace either :pending or :active
trait :suspended, :user do
  from [:pending, :active]
  exec :suspend_user
end

# execute :create_user command
produce(ctx, user: [:pending])

# execute :create_user -> :activate_user
produce(ctx, user: [:active])

# execute :create_user -> :suspend_user
produce(ctx, user: [:suspended])

# execute :create_user -> :activate_user -> :suspend_user
ctx |> produce(user: [:active]) |> produce(user: [:suspended])
Same trait from multiple commands
The same trait can be defined multiple times with different commands. This is useful when the same state
can be reached through different paths in your business logic:
# User can become :active through a state transition...
trait :active, :user do
  from :pending
  exec :activate_user
end

# ...or directly via a command that creates an already-active user
trait :active, :user do
  exec :create_active_user
end

# Unique marker for the direct path
trait :pending_skipped, :user do
  exec :create_active_user
end
When several commands can provide a trait, SeedFactory chooses one that fits
the plan. To require a specific path, request a trait unique to that command:
# Either path can provide :active
produce(ctx, user: [:active])

# Force the direct path by requesting :pending_skipped trait
produce(ctx, user: [:active, :pending_skipped])
Exec step
The exec directive inside a trait specifies which command must be executed
to mark the entity with the trait.
Options
	:args_pattern - a map with args. If the command args match the pattern, the entity is marked with the trait.
The pattern is also used to generate args when the entity is requested with this trait.
	:args_match - a function that accepts command args and returns a boolean. Must be used with :generate_args.
	:generate_args - a function that generates a map with args satisfying :args_match. Must be used with :args_match.

:args_pattern is a simpler alternative to the :args_match + :generate_args combination.
Parameterized traits
A parameterized trait accepts a value in produce or with_traits.
Put _ in :args_pattern where the command should receive that value:
command :create_user do
  param :age, value: 21

  resolve(fn args -> MyApp.Users.create_user(args) end)

  produce :user
end

trait :age, :user do
  exec :create_user, args_pattern: %{age: _}
end

produce(ctx, user: [age: 18])
Here, produce passes age: 18 to :create_user. After the command runs,
SeedFactory records {:age, 18} in the user's traits. A direct exec/3 call
records the trait in the same way, using the value from the command arguments.
A dependency can require the same value through with_traits:
param :user, entity: :user, with_traits: [age: 18]
Other fields in the pattern must match too. For example,
%{age: _, role: :admin} records the trait only when the command receives
role: :admin.
The rules:
	Each parameterized trait uses exactly one _ placeholder as a map value,
for example %{age: _} or %{settings: %{locale: _}}.
	A parameterized trait requires one value, which can be any Elixir term.
Use separate traits for separate arguments.
	Values are compared with ===, so 18 and 18.0 are different values.
	from can only name ordinary traits. A parameterized trait can use from
to replace an ordinary trait; its own previous value is replaced automatically.
	:as is reserved for rebinding and cannot name a parameterized trait.

Existing entities and value changes
Requesting a value already recorded in the entity's traits does not run
another command. To change the value, add an update command and another
declaration of the same trait to the schema above:
command :set_age do
  param :user, entity: :user
  param :age

  resolve(fn args -> MyApp.Users.set_age(args.user, args.age) end)

  update :user
end

trait :age, :user do
  exec :set_age, args_pattern: %{age: _}
end

ctx = produce(ctx, user: [age: 18]) # runs :create_user
ctx = produce(ctx, user: [age: 18]) # runs nothing
ctx = produce(ctx, user: [age: 21]) # runs :set_age on the same user
After the update, {:age, 21} replaces {:age, 18} in the user's traits.
Without an update command for the trait, requesting a different value fails
before execution.
Ordinary trait matching and argument generation
Use args_pattern when a trait requires fixed argument values:
trait :admin, :user do
  exec :create_user, args_pattern: %{role: :admin}
end

trait :normal, :user do
  exec :create_user, args_pattern: %{role: :normal}
end
The equivalent declarations using functions are:
trait :admin, :user do
  exec :create_user do
    generate_args(fn -> %{role: :admin} end)
    args_match(&match?(%{role: :admin}, &1))
  end
end

trait :normal, :user do
  exec :create_user do
    generate_args(fn -> %{role: :normal} end)
    args_match(&match?(%{role: :normal}, &1))
  end
end
Use args_match and generate_args when the condition cannot be expressed
with fixed values. args_match checks whether the arguments satisfy the trait;
generate_args supplies arguments that satisfy it when the trait is requested.
For example, an expiration check depends on today's date:
trait :not_expired, :project do
  exec :publish_project do
    args_match(fn args -> Date.compare(Date.utc_today(), args.expiry_date) in [:lt, :eq] end)

    generate_args(fn ->
      today = Date.utc_today()
      %{start_date: today, expiry_date: Date.add(today, 21)}
    end)
  end
end

trait :expired, :project do
  exec :publish_project do
    args_match(fn args -> Date.compare(Date.utc_today(), args.expiry_date) == :gt end)

    generate_args(fn ->
      today = Date.utc_today()
      %{start_date: Date.add(today, -22), expiry_date: Date.add(today, -1)}
    end)
  end
end
generate_args runs once during planning, before any command executes.
The command then uses those generated arguments. Keep this function free of
database and file writes. SeedFactory also evaluates args_match during
planning when the required arguments are known; if it needs an entity that
has not been created yet, the check waits until that entity is available.
Splitting large schemas with fragments
SeedFactory uses Spark for its DSL. Spark provides a mechanism
called Spark.Dsl.Fragment that allows splitting a large DSL module into multiple files.
When a schema grows large, you can extract groups of related commands and traits into fragments.
Each fragment can contain commands and traits, and they are merged into the main schema at compile time.
defmodule MyApp.SeedFactorySchema.UserCommands do
  use Spark.Dsl.Fragment,
    of: SeedFactory.Schema

  command :create_user do
    param :name, generate: &Faker.Person.name/0
    param :role, value: :normal

    resolve(fn args -> MyApp.Users.create_user(args) end)

    produce :user
  end

  command :activate_user do
    param :user, entity: :user, with_traits: [:pending]

    resolve(fn args ->
      {:ok, %{user: MyApp.Users.activate_user!(args.user)}}
    end)

    update :user
  end

  trait :pending, :user do
    exec :create_user
  end

  trait :active, :user do
    from :pending
    exec :activate_user
  end
end

defmodule MyApp.SeedFactorySchema do
  use SeedFactory.Schema,
    fragments: [MyApp.SeedFactorySchema.UserCommands]

  # other commands go here
end
Fragments can reference entities from other fragments or from the main schema —
dependency resolution works across all of them.
Include schemas
It is possible to include multiple schemas into a new schema in order to reuse everything that is declared in specified modules.
defmodule MyAppWeb.SeedFactorySchema do
  use SeedFactory.Schema

  include_schema MyApp.SeedFactorySchema

  # Web-specific stuff goes here. You may need such a separation of modules
  # if you have an umbrella project and web is a separate app
  command :build_conn do
    resolve(fn _ ->
      conn =
        Phoenix.ConnTest.build_conn()
        |> Plug.Conn.put_private(:phoenix_endpoint, MyAppWeb.Endpoint)
      {:ok, %{conn: conn}}
    end)

    produce :conn
  end

  command :create_user_session do
    param :user, entity: :user, with_traits: [:active]
    param :conn, entity: :conn, with_traits: [:unauthenticated]

    resolve(fn args ->
      {:ok, %{conn: MyAppWeb.Session.init_user_session(args.conn, args.user)}}
    end)

    update :conn
  end

  trait :unauthenticated, :conn do
    exec :build_conn
  end

  trait :user_session, :conn do
    from :unauthenticated
    exec :create_user_session
  end
end

Integrates SeedFactory with ExUnit.
Usage
Add the following line to your test modules:
use SeedFactory.Test, schema: MySeedFactorySchema
This will:
	initialize the schema via SeedFactory.init/2 in a setup_all callback
	import SeedFactory functions:	SeedFactory.exec/3
	SeedFactory.produce/2
	SeedFactory.rebind/3
	SeedFactory.pre_exec/3
	SeedFactory.pre_produce/2


	import the produce/1 macro (see below)

          @spec produce(
  SeedFactory.entity_name()
  | [
      SeedFactory.entity_name()
      | SeedFactory.rebinding_rule()
      | {SeedFactory.entity_name(), [SeedFactory.trait_request()]}
    ]
) :: Macro.t()


      


A macro for producing entities outside of test blocks.
Generates a setup callback that calls SeedFactory.produce/2, so the entities
are available in all tests within the scope. Accepts the same arguments as produce/2. This:
produce [:company, user: [:active, :admin]]
is equivalent to:
setup context do
  produce(context, [:company, user: [:active, :admin]])
end
Can only be called outside of test blocks. For producing entities inside a test,
use SeedFactory.produce/2 directly.
Examples
produce :company

test "my test", %{company: company} do
  assert my_function(company)
end
produce [:company, user: [:active, :admin, as: :active_admin]]

test "my test", %{company: company, active_admin: admin} do
  assert my_function(company, admin)
end
produce org: :org1
produce org: :org2

test "my test", %{org1: org1, org2: org2} do
  assert my_function(org2, org1)
end

SeedFactory.ExecError exception
    






  

    
SeedFactory.MissingRequestedTraitError exception

SeedFactory.TraitPathNotFoundError exception
    






  

    
SeedFactory.TraitRemovedByCommandError exception
    






  

    
SeedFactory.TraitResolutionError exception

SeedFactory.UnknownTraitError exception
    






  

    
SeedFactory.UnproducibleEntityError exception

